(選股腳本)WMA黃金交叉，點選任一日期顯示無任何符合選股條件的商品

  •   20 
  • 最後發表   andrew1234  1 週前
andrew1234 發文於   2025/10/08

請教各位大大，(選股腳本)WMA黃金交叉，改成指標可以show出指標，回測也可以看到有篩選出股票，但點選任一日期卻顯示無任何符合選股條件的商品，請問是哪裡有問題嗎?


{-------------------------------

 指標名稱: WMA Cross (20 vs 50)

 功能: 顯示 WMA(20) 與 WMA(50)，並標示黃金交叉與死亡交叉

--------------------------------}

 

Inputs:

    FastLen(20),        // 快線週期

    SlowLen(50),        // 慢線週期

    Price(Close);        // 使用價格序列

 

Vars:

    FastWMA(0),

    SlowWMA(0),

    FactorFast(0),

    FactorSlow(0),

    CrossUp(false),

    CrossDown(false);

 

{-------------------------------

    計算權重因子

--------------------------------}

if FactorFast = 0 then FactorFast = 0.5 * FastLen * (FastLen + 1);

if FactorSlow = 0 then FactorSlow = 0.5 * SlowLen * (SlowLen + 1);

 

{-------------------------------

    計算 Fast WMA(20)

--------------------------------}

if CurrentBar < FastLen then

    FastWMA = Price

else begin

    FastWMA = FastLen * Price;

    for value1 = 1 to FastLen - 1 begin

        FastWMA += Price[value1] * (FastLen - value1);

    end;

    FastWMA = FastWMA / FactorFast;

end;

 

{-------------------------------

    計算 Slow WMA(50)

--------------------------------}

if CurrentBar < SlowLen then

    SlowWMA = Price

else begin

    SlowWMA = SlowLen * Price;

    for value2 = 1 to SlowLen - 1 begin

        SlowWMA += Price[value2] * (SlowLen - value2);

    end;

    SlowWMA = SlowWMA / FactorSlow;

end;

 

condition1=FastWMA >= SlowWMA;

condition2=FastWMA[1] < SlowWMA[1];

if condition1 and condition2 then ret = 1;

排序方式: 標準 | 最新
虎科大許教授 發文於   2025/10/09

(1)問題出在讀取資料筆數。用setTotalBar增加讀取資料筆數即可。

(2)WMA是內建函數，不需要自己運算，直接呼叫即可。

setTotalBar(50);
Inputs:
    FastLen(20),        // 快線週期
    SlowLen(50),        // 慢線週期
    Price(Close);        // 使用價格序列  
Vars:
    FastWMA(0),
    SlowWMA(0);
FastWMA=wma(price,FastLen);
SlowWMA=wma(price,SlowLen);
if FastWMA cross over SlowWMA then ret=1;
outputField1(FastWMA,"FastWMA");
outputField2(SlowWMA,"SlowWMA");

andrew1234 發文於   2025/10/09

感謝許教授!!

發表回覆
發表新主題
我的發文
我的收藏
分類
Close