如何將加權指數(日資料)的KD值加入策略雷達

538
最後發表 WilliamL 2023 四月 06

WilliamL 發文於 2019/08/26

大家好：

分享如何用警示腳本撰寫，將加權指數的KD值加入判斷。

大致撰寫邏輯：

1.使用Stochastic函數內容，得知所需資料

2.使用GetSymbolField語法，指定抓取加權指數"TSE.TW"之所需資料

3.新增自訂函數：取名為TSE_Stochastic，將Stochastic的資料內容，修改為加權指數資料。

4.將新自訂函數TSE_Stochastic進行後續應用。

TSE_Stochastic範例語法如下：

SetBarMode(2);

// Stochastic function (for KD/RSV相關指標)
//
// Input: length, rsvt, kt
// Return: rsv_value, k_value, d_value
//
input:
    length(numericsimple), rsvt(numericsimple), kt(numericsimple),
    rsv(numericref), k(numericref), d(numericref);

variable:
    maxHigh(0), minLow(0);

maxHigh = Highest(GetSymbolField("TSE.TW","high","D"), length);
minLow = Lowest(GetSymbolField("TSE.TW","low","D"), length);

if maxHigh <> minLow then
    rsv = 100 * (GetSymbolField("TSE.TW","close","D") - minLow) / (maxHigh - minLow)
else
    rsv = 50;

if currentbar = 1 then
  begin
    k = 50;
    d = 50;
  end
else
  begin
    k = (k[1] * (rsvt - 1) + rsv) / rsvt;
    d = (d[1] * (kt - 1) + k) / kt;
  end;  

tse_stochastic= 1;

警示範例如下：

input: Length_D(9, "日KD期間"),rsvt(3,"K平滑期數"), kt(3,"D平滑期數");

value1 = tse_Stochastic(Length_D,rsvt,kt,value2,value3,value4);

if value3 cross over value4  //如果大盤K值向上超過大盤D值
    then begin
    if close>high[1]  //收盤價>前一根最高價
    then ret=1 ;
    end;